Pembuatan Konfigurasi INI File Dengan Visual Basic (VB6)

Pada umumnya file-file yang berekstensi *.ini digunakan pada sistem windows untuk file setting mengenai running sebuah proses yang sedang berlangsung pada windows. Untuk kali ini admin kan sedikit share tentang bagaimana caranya pembuatan sebuah file dengan ekstensi *.ini dengan menuliskan beberapa karakter pada file *.ini tersebut. Pada umumnya file berekstensi *.ini digunakan sebagai file acuan setting dari sebuah aplikasi yang dibuat, misalkan setting dari koneksi database, file source tujuan backup database dan masih banyak yang lainnya.

Langsung saja masuk ke pokok pembahasan, buka Aplikasi Visual Basic 6.0 (VB6) dengan menggunakan StandartExe, lalu tambahkan beberapa komponen pada Form yang baru agan buat : TextBox dan CommandButton, terserah agan-agan mau diberi name apa aja, disini ane untuk namenya default. Seperti dibawah ini : 

Kemudian tambahkan juga 2 buah module variabel-variabel Function Dibawah ini

Modul 1

Public Function ReadIniValue(INIpath As String, KEY As String, Variable As String) As String
Dim NF As Integer
Dim Temp As String
Dim LcaseTemp As String
Dim ReadyToRead As Boolean
 
AssignVariables:
        NF = FreeFile
        ReadIniValue = ""
        KEY = "[" & LCase$(KEY) & "]"
        Variable = LCase$(Variable)
 
EnsureFileExists:
    Open INIpath For Binary As NF
    Close NF
    SetAttr INIpath, vbArchive
 
LoadFile:
    Open INIpath For Input As NF
    While Not EOF(NF)
    Line Input #NF, Temp
    LcaseTemp = LCase$(Temp)
    If InStr(LcaseTemp, "[") <> 0 Then ReadyToRead = False
    If LcaseTemp = KEY Then ReadyToRead = True
    If InStr(LcaseTemp, "[") = 0 And ReadyToRead = True Then
        If InStr(LcaseTemp, Variable & "=") = 1 Then
            ReadIniValue = Mid$(Temp, 1 + Len(Variable & "="))
            Close NF: Exit Function
            End If
        End If
    Wend
    Close NF
End Function

Module 2

Public Function WriteIniValue(INIpath As String, PutKey As String, PutVariable As String, PutValue As String)
Dim Temp As String
Dim LcaseTemp As String
Dim ReadKey As String
Dim ReadVariable As String
Dim LOKEY As Integer
Dim HIKEY As Integer
Dim KEYLEN As Integer
Dim VAR As Integer
Dim VARENDOFLINE As Integer
Dim NF As Integer
Dim X As Integer
AssignVariables:
    NF = FreeFile
    ReadKey = vbCrLf & "[" & LCase$(PutKey) & "]" & Chr$(13)
    KEYLEN = Len(ReadKey)
    ReadVariable = Chr$(10) & LCase$(PutVariable) & "="
       
EnsureFileExists:
    Open INIpath For Binary As NF
    Close NF
    SetAttr INIpath, vbArchive
   
LoadFile:
    Open INIpath For Input As NF
    Temp = Input$(LOF(NF), NF)
    Temp = vbCrLf & Temp & "[]"
    Close NF
    LcaseTemp = LCase$(Temp)
   
LogicMenu:
    LOKEY = InStr(LcaseTemp, ReadKey)
    If LOKEY = 0 Then GoTo AddKey:
    HIKEY = InStr(LOKEY + KEYLEN, LcaseTemp, "[")
    VAR = InStr(LOKEY, LcaseTemp, ReadVariable)
    If VAR > HIKEY Or VAR < LOKEY Then GoTo AddVariable:
    GoTo RenewVariable:
   
AddKey:
        Temp = Left$(Temp, Len(Temp) - 2)
        Temp = Temp & vbCrLf & vbCrLf & "[" & PutKey & "]" & vbCrLf & PutVariable & "=" & PutValue
        GoTo TrimFinalString:
       
AddVariable:
        Temp = Left$(Temp, Len(Temp) - 2)
        Temp = Left$(Temp, LOKEY + KEYLEN) & PutVariable & "=" & PutValue & vbCrLf & Mid$(Temp, LOKEY + KEYLEN + 1)
        GoTo TrimFinalString:
       
RenewVariable:
        Temp = Left$(Temp, Len(Temp) - 2)
        VARENDOFLINE = InStr(VAR, Temp, Chr$(13))
        Temp = Left$(Temp, VAR) & PutVariable & "=" & PutValue & Mid$(Temp, VARENDOFLINE)
        GoTo TrimFinalString:
TrimFinalString:
        Temp = Mid$(Temp, 2)
        Do Until InStr(Temp, vbCrLf & vbCrLf & vbCrLf) = 0
        Temp = Replace(Temp, vbCrLf & vbCrLf & vbCrLf, vbCrLf & vbCrLf)
        Loop
   
        Do Until Right$(Temp, 1) > Chr$(13)
        Temp = Left$(Temp, Len(Temp) - 1)
        Loop
   
        Do Until Left$(Temp, 1) > Chr$(13)
        Temp = Mid$(Temp, 2)
        Loop
   
OutputAmendedINIFile:
        Open INIpath For Output As NF
        Print #NF, Temp
        Close NF
End Function

Double klik pada CommandButton1 dan agan pastekan aja script dibawah ini : 

WriteIniValue App.Path & "\Setting.ini", "KONEKSI DATABASE Mysql", "SERVER", Text1.Text
WriteIniValue App.Path & "\Setting.ini", "KONEKSI DATABASE Mysql", "USER", Text2.Text
WriteIniValue App.Path & "\Setting.ini", "KONEKSI DATABASE Mysql", "PASSWORD", Text3.Text
WriteIniValue App.Path & "\Setting.ini", "KONEKSI DATABASE Mysql", "DATABASE", Text4.Text

Jangan lupa untuk menampilkan datanya double klik pada Form dan Pilih Prosedur Form_Load

Text1.Text = ReadIniValue(App.Path & "\Setting.ini", "KONEKSI DATABASE Mysql", "SERVER")
Text2.Text = ReadIniValue(App.Path & "\Setting.ini", "KONEKSI DATABASE Mysql", "USER")
Text3.Text = ReadIniValue(App.Path & "\Setting.ini", "KONEKSI DATABASE Mysql", "PASSWORD")
Text4.Text = ReadIniValue(App.Path & "\Setting.ini", "KONEKSI DATABASE Mysql", "DATABASE")

Save kemudian Run / F5, inputkan datanya pada textbox kemudian simpan. Hasilnya seperti dibawah ini 

Kalau masih kurang mengerti bisa langsung download di sini